Mikrotik Skript: E-Mail Benachrichtigung über neue MAC-Adressen im Netzwerk

# Dateiname zur Sicherung der MACs 
:local filename "known-macs.txt"  
# Welche DHCP Server Leases sollen überwacht werden (Achtung bitte Regular Expression String benutzen / Ein Punkt berücksichtigt alle DHCP-Server)
:local dhcpserver "."  
# Absender-Adresse
:local MAILFROM "userfrom@domain.de"  
# Empfänger-Adresse
:local MAILTO "userto@domain.de"  
# aktuelle leases der angegebenen DHCP-Server holen
:local leases [/ip dhcp-server lease print as-value where server ~ "$dhcpserver"]  
# variables
:local newmacs ""  
:local foundnew false
:local mailbody ""  
:local filedata ""  

:if ([/file find name=$filename] != "") do={  
    # Datei mit bekannten MAC-Adressen existiert, setze Variable mit Inhalt
    :set filedata [/file get $filename contents]
} else={
    # Datei mit bekannten MAC-Adressen existiert noch nicht, erstelle Datei
    /file print from=0 file=$filename
    :delay 1
}

# Prüfe jede MAC ob sie noch nicht in der Datei vorhanden ist
:foreach mac in=$leases do={
    :if ([:find $filedata ($mac->"mac-address")] < 0) do={  
            :set newmacs ($newmacs . ($mac->"mac-address") . ";" . ($mac->"host-name") . "\r\n")  
            :set mailbody ($mailbody . "MAC-ADRESSE: " . ($mac->"mac-address") . "\r\nHOSTNAME: " . ($mac->"host-name") . "\r\nSERVER: " . ($mac->"server") . "\r\nIP: " . ($mac->"address"). "\r\n=============")  
            :set foundnew true
    }
}

# wenn neue MACs vorhanden sind schreibe sie in die Datei zurück, schreibe Info ins Log und benachrichtige per Mail
:if ($foundnew = true) do={
    /file set $filename contents=($filedata . $newmacs)
    :log warning ("Neu erkannte MAC-Adressen im Netzwerk:\r\n" . $mailbody)  

    /tool e-mail send to="$MAILTO" subject="Neue MAC-Adresse(n) im Netzwerk" from="$MAILFROM" body=("Es wurde(n) neue MAC-Adresse(n) im Netzwerk registriert:\r\n" . $mailbody)  
}